Add gnal 50ft v1 and required dependency files

main
mmcwilliams 3 years ago
parent c971a2c54a
commit 133e5e0bcd
  1. 769
      50ft_v1/gnal_50ft.scad
  2. 195
      50ft_v1/path_extrude.scad
  3. 3
      50ft_v1/spacer.scad
  4. 3
      50ft_v1/spiral_bottom.scad
  5. 3
      50ft_v1/spiral_top.scad
  6. 372
      50ft_v1/threads.scad
  7. 3
      50ft_v1/top.scad

@ -0,0 +1,769 @@
include <./threads.scad>;
//https://www.thingiverse.com/thing:186660
include <./path_extrude.scad>;
$fn = 20;
H = 9.71;
REEL_H = 42;
REEL_D = 225.67 + .4;
REEL_OUTER_WALL_H = 7.5;
REEL_OUTER_WALL_W = 5.9;
REEL_INNER_D = 50;
REEL_INNER_H = 7.5;
REEL_INNER_WALL_W = 20;
REEL_MIDDLE_D = ((REEL_D - REEL_INNER_D) / 2) + REEL_INNER_D;
REEL_MIDDLE_WALL_H = 7.5;
REEL_MIDDLE_WALL_W = 3;
SPOKE_COUNT = 24;
OD = 10;
PITCH = 1.5;
THREAD = 1.6;
LEN = 21;
/**
* Frame which the bottom of the spiral reel is mounted to.
*/
module reel_frame () {
//outer wall
difference () {
cylinder(r = REEL_D / 2, h = REEL_OUTER_WALL_H, center = true);
cylinder(r = (REEL_D / 2) - REEL_OUTER_WALL_W, h = REEL_OUTER_WALL_H + 1, center = true);
}
difference () {
cylinder(r = REEL_MIDDLE_D / 2, h = REEL_MIDDLE_WALL_H, center = true);
cylinder(r = (REEL_MIDDLE_D / 2) - REEL_MIDDLE_WALL_W, h = REEL_MIDDLE_WALL_H + 1, center = true);
}
//inner wall
difference () {
cylinder(r = REEL_INNER_D / 2, h = REEL_INNER_H, center = true);
cylinder(r = (REEL_INNER_D / 2) - REEL_INNER_WALL_W, h = REEL_INNER_H + 1, center = true);
}
//standoff
B = 8.15;
D = 10.63;
OUTER = ((D * 2) + B) / 2;
INNER = B / 2;
translate ([0, 0, 4]) {
difference () {
cylinder(r = OUTER, h = 8, center = true);
cylinder(r = INNER, h = 8 + 1, center = true);
translate([0, 0, -8]) metric_thread (diameter=OD, pitch=PITCH, thread_size = THREAD, length=LEN);
}
translate([0, 13, 0]) rotate([0, 0, 45]) cube([8, 8, 8], center = true);
}
//spokes
spokes();
rotate([0, 0, 360 / (SPOKE_COUNT * 2)]) {
difference() {
spokes();
cylinder(r = REEL_MIDDLE_D / 2, h = REEL_MIDDLE_WALL_H + 1, center = true);
}
}
}
/**
* Spokes structure for the spiral reel frame
*/
module spokes () {
for (i = [0 : SPOKE_COUNT]) {
rotate([0, 0, i * (360 / SPOKE_COUNT)]) {
translate([0, (REEL_INNER_D / 2) + ((REEL_D - REEL_INNER_D) / 4) - 1, 0]) {
cube([3, (REEL_D - REEL_INNER_D) / 2, REEL_OUTER_WALL_H], center = true);
}
}
}
}
/**
* The bottom spiral
*/
module spiral_bottom_old () {
union () {
difference () {
translate([0, 0, (-(H - REEL_OUTER_WALL_H) / 2) - .05]) reel_frame();
}
rotate([0, 0, 270]) scale([-1, 1, 1]) spiral();
}
}
/**
* Only needed for 50ft model, not the current target ATM.
*/
module spiral_top_old () {
union () {
difference () {
translate([0, 0, (-(H - REEL_OUTER_WALL_H) / 2) - .05]) reel_frame();
}
rotate([0, 0, 270]) scale([-1, 1, 1]) spiral();
}
}
/**
* Render all spiral facets for as many rotations as supplied
Using new module
*/
module spiral (START_D = 50, SPIRALS = 39) {
//STOP_D = 100;
SPACING = 0.86;//1.34;
TOP_T = 0.86; //thickness
BOTTOM_T = 1.4;
START_R = START_D / 2;
union () {
for (i = [0 : $fn]) {
rotate ([0, 0, i * (360 / $fn)]) {
for (x = [0: (SPIRALS - 1)]) {
spiral_facet(i, x, START_R, SPACING, BOTTOM_T, TOP_T, H);
}
}
}
}
}
/**
* Generates a single face of the spiral, in this case a trapazoidal
* shape. Issues are (1) performance (maybe use of hull()) and (2) all
* facet lenths are the same, despite the diameter. This means that
* there are excessive numbers of facets for the smaller spirals to
* compensate for the number of facets needed for the outer spiral.
*/
module spiral_facet (i, x, START_R, SPACING, BOTTOM_T, TOP_T, H) {
STEP_SIZE = ((SPACING + BOTTOM_T) / $fn);
STEP_OFFSET = i * STEP_SIZE;
SPIRAL_START_OFFSET = (x * (SPACING + BOTTOM_T));
ACTUAL_R = START_R + SPIRAL_START_OFFSET + STEP_OFFSET;
L = 2 * (ACTUAL_R * tan((360 / $fn) / 2));
ANGLE = -atan( STEP_SIZE / (L / 2) ) / 2;
OFFSET = START_R - (BOTTOM_T / 2) + SPIRAL_START_OFFSET + STEP_OFFSET;
translate ([OFFSET, 0, - H / 2]) {
rotate ([0, 0, ANGLE]) {
//replace hull for quick render?
//test spiral lib
hull () {
translate([0, 0, H])
cube([TOP_T, L, 0.1], center=true);
cube([BOTTOM_T, L, 0.1], center=true);
}
}
}
}
/**
* Generates an arc with a diameter, width, height and total angle.
*/
module arc (D, W, H, ANGLE) {
R = D / 2;
difference () {
cylinder(r = R, h = H, center = true);
cylinder(r = R - W, h = H + 1, center = true);
if (ANGLE <= 90) {
translate([-R, -R, 0]) cube([D, D, H + 1], center=true);
translate([-R, R, 0]) cube([D, D, H + 1], center=true);
translate([R, -R, 0]) cube([D, D, H + 1], center=true);
rotate ([0, 0, ANGLE]) {
translate([R, R, 0]) {
cube([D, D, H + 1], center=true);
}
}
} else if (ANGLE <= 180) {
translate([-R, -R, 0]) cube([D, D, H + 1], center=true);
translate([R, -R, 0]) cube([D, D, H + 1], center=true);
rotate ([0, 0, ANGLE]) {
translate([R, R, 0]) {
cube([D, D, H + 1], center=true);
}
}
} else if (ANGLE <= 270) {
translate([R, -R, 0]) cube([D, D, H + 1], center=true);
rotate ([0, 0, ANGLE]) {
translate([R, R, 0]) {
cube([D, D, H + 1], center=true);
}
}
} else if (ANGLE <= 360) {
difference () {
union () {
difference () {
cylinder(r = R + 1, h = H + 1, center = true);
cylinder(r = R - W - 1, h = H + 2, center = true);
}
}
scale ([1, -1, 1]) {
translate([-R, -R, 0]) cube([D, D, H + 1], center=true);
translate([-R, R, 0]) cube([D, D, H + 1], center=true);
translate([R, -R, 0]) cube([D, D, H + 1], center=true);
rotate ([0, 0, 360 - ANGLE]) {
translate([R, R, 0]) {
cube([D, D, H + 1], center=true);
}
}
}
}
}
}
}
module film () {
//sample film
arc(REEL_D - 4, .5, 16, 100);
}
module spiral_top_old_debug (half = false, top = false) {
difference () {
translate([0, 0, 37]) rotate([180, 0, 180]) spiral_top_old();
if (half) {
rotate([0, 0, 80]) translate([50, 0, 0]) cube([100, 100, 100], center = true); //half
}
if (top) {
translate([0, 0, 60]) cube([100, 100, 100], center = true); //just top
}
}
}
module spiral_bottom_old_debug () {
difference () {
spiral_bottom_old();
rotate([0, 0, 80]) translate([50, 0, 0]) cube([100, 100, 100], center = true);
}
}
module exploded_view () {
spiral_bottom_old();
translate([0, 0, 37 + 15]) rotate([180, 0, 180]) spiral_top_old();
translate([0, 0, -10]) spiral_top_old_cap();
}
module spiral_test () {
//$fn = 100;
//spiral(START_D=34,SPIRALS=8);
translate([0, 0, (-(H - REEL_OUTER_WALL_H) / 2) - .05]) {
//difference () {
intersection() {
reel_frame();
cylinder(r = 35, h = H + 20, center = true);
}
//cylinder(r = 22, h = H, center = true);
//}
}
}
module spiral_bottom_core (thread = false) {
$fn = 360;
core_center_h = 3;
core_bottom_outer_d = 53;
core_bottom_outer_void_d = 44;
core_bottom_outer_h = 4.2;
core_d = 29.5;
core_h = 8.5;
core_bottom_d = 26;
core_bottom_h = 5;
top_z_offset = (core_h / 2) - (core_center_h / 2);
arms_outer_d = 48;
arms_inner_d = 48 - 7;
core_void_outer_d = 20.5;
core_void_inner_d = 14.5;
core_void_h = 11.5;
film_void = 0.8;
translate([0, 0, -(core_bottom_outer_h / 2) - (core_center_h / 2) ]) difference () {
cylinder(r = core_bottom_outer_d / 2, h = core_bottom_outer_h + core_center_h, center = true);
cylinder(r = core_bottom_outer_void_d / 2, h = core_bottom_outer_h + core_center_h + 1, center = true);
}
difference () {
union() {
//center
translate([0, 0, -core_center_h / 2]) {
difference () {
cylinder(r = (core_bottom_outer_d - 1) / 2, h = core_center_h, center = true);
rotate([0, 0, -120]) translate([20, 0, 0]) rotate([0, 0, 45]) cube([20, 20, 20], center = true);
}
translate([0, 0, -1]) cylinder(r = core_d / 2, h = core_center_h, center = true);
}
//top
translate([0, 0, top_z_offset]) {
cylinder(r = core_d / 2, h = core_h + core_center_h, center = true);
}
//bottom
translate([0, 0, -(core_bottom_h / 2) - (core_center_h / 2)]) {
cylinder(r = core_bottom_d / 2, h = core_bottom_h + core_center_h, center = true);
}
}
//thread
if (thread) {
translate([0, 0, -LEN / 2]) metric_thread (diameter=OD + .2, pitch=PITCH, thread_size = THREAD, length=LEN);
} else {
cylinder(r = (OD + 0.2) / 2, h = LEN, center = true);
}
translate([0, 0, -2.3]) difference () {
cylinder(r = core_void_outer_d / 2, h = core_void_h, center = true);
cylinder(r = core_void_inner_d / 2, h = core_void_h + 1, center = true);
}
}
//arms
difference () {
union () {
translate([0, 0, top_z_offset]) difference() {
//adjust one arm inward
intersection () {
cylinder(r = arms_outer_d / 2, h = core_h + core_center_h, center = true);
translate([1, 0, 0]) cylinder(r = arms_outer_d / 2, h = core_h + core_center_h, center = true);
}
intersection () {
cylinder(r = arms_inner_d / 2, h = core_h + core_center_h + 1, center = true);
translate([1, 0, 0]) cylinder(r = arms_inner_d / 2, h = core_h + core_center_h + 1, center = true);
}
translate([0, arms_outer_d / 2, 0]) cube([arms_outer_d, arms_outer_d, arms_outer_d], center = true);
}
translate([(arms_outer_d + arms_inner_d) / 4, 0, top_z_offset]) cylinder(r = 3.5 / 2, h = core_h + core_center_h, center = true, $fn = 40);
//adjusted arm
translate([-((arms_outer_d + arms_inner_d) / 4) + 1, 0, top_z_offset]) cylinder(r = 3.5 / 2, h = core_h + core_center_h, center = true, $fn = 40);
difference () {
rotate([0, 0, -120]) translate([13.75, 0, top_z_offset]) cube([16, 20, core_h + core_center_h], center = true);
//remove piece from adjusting arm
translate([-19, -14, 0]) rotate([0, 0, 10]) cube([4, 4, 30], center = true);
rotate([0, 0, -120 - 37]) translate([18, 0, top_z_offset]) {
cylinder(r = 6.8 / 2, h = 30, center = true);
translate([-4, -2, 0]) cube([4, 4, 30], center = true);
}
rotate([0, 0, -120 + 37]) translate([18, 0, top_z_offset]) {
cylinder(r = 6.8 / 2, h = 30, center = true);
translate([-4, 2, 0]) cube([4, 4, 30], center = true);
}
}
}
rotate([0, 0, -120]) translate([20, -5, 0]) rotate([0, 0, 45]) cube([20, film_void, 30], center = true);
rotate([0, 0, -120]) translate([20, 5, 0]) rotate([0, 0, -45]) cube([20, film_void, 30], center = true);
rotate([0, 0, -120]) translate([25, 0, 0]) difference () {
cylinder(r = 8 / 2, h = 30, center = true);
translate([-6.9, 0, 0]) cube([8, 8, 30], center = true);
}
cylinder(r = core_void_outer_d / 2, h = core_void_h, center = true);
rotate([0, 0, -120]) translate([20, 0, -1.5]) rotate([0, 0, 45]) cube([20, 20, 3.01], center = true);
}
}
module spiral_bottom (threads = false, spiral_count = 40) {
outer_d = 215;
outer_d_inside = 209;
outer_h = 7.5;
spoke_len = 81;
spoke_w = 3;
spoke_h = 4.2 + 3;
spoke_2_len = 43;
spoke_2_h = 6;
translate([0, 0, -3.75]) difference () {
cylinder(r = outer_d / 2, h = outer_h, center = true, $fn = 500);
cylinder(r = outer_d_inside / 2, h = outer_h + 1, center = true, $fn = 500);
}
//rounding voids
difference () {
spiral_bottom_core(threads);
for (i = [0 : SPOKE_COUNT]) {
rotate([0, 0, (i + 0.5) * (360 / SPOKE_COUNT)]) translate([0, 26.75, 0]) cylinder(r = 2, h = 20, center = true, $fn = 40);
}
}
for (i = [0 : SPOKE_COUNT]) {
rotate([0, 0, i * (360 / SPOKE_COUNT)]) translate([(spoke_len / 2) + (48 / 2), 0, -3.6]) cube([spoke_len, spoke_w, spoke_h], center = true);
}
for (i = [0 : SPOKE_COUNT]) {
rotate([0, 0, (i + 0.5) * (360 / SPOKE_COUNT)]) translate([(outer_d / 2) - (spoke_2_len / 2) - 2, 0, -3]) cube([spoke_2_len, spoke_w, spoke_2_h], center = true);
}
for (i = [0 : SPOKE_COUNT]) {
rotate([0, 0, (i + 0.5) * (360 / SPOKE_COUNT)]) translate([63, 0, -3]) rotate([0, 0, 20]) cube([ spoke_w, 18, spoke_2_h], center = true);
}
//translate([0, 0, 1]) rotate([0, 0, 0]) spiral_2 (START_D = 46.95, SPIRALS = spirals); //12 //40
translate([0, 0, -.1]) spirals(spiral_count, 46.95 - 1.2, 2.075);
}
module spiral_top_core () {
$fn = 360;
core_center_h = 3;
core_bottom_outer_d = 53;
core_bottom_outer_void_d = 44;
core_bottom_outer_h = 4.2;
core_d = 29.5;
core_h = 8.5;
core_bottom_d = 26;
core_bottom_h = 4.2;
top_z_offset = (core_h / 2) - (core_center_h / 2);
core_void_outer_d = 20.5;
core_void_inner_d = 14.5;
core_void_h = 11.5;
arms_outer_d = 48;
arms_inner_d = 48 - 7;
void_d = 18;
film_void = 0.8;
translate([0, 0, -(core_bottom_outer_h / 2) - (core_center_h / 2) ]) difference () {
cylinder(r = core_bottom_outer_d / 2, h = core_bottom_outer_h + core_center_h, center = true);
cylinder(r = core_bottom_outer_void_d / 2, h = core_bottom_outer_h + core_center_h + 1, center = true);
}
difference () {
union() {
//center
translate([0, 0, -core_center_h / 2]) {
difference () {
cylinder(r = (core_bottom_outer_d - 1) / 2, h = core_center_h, center = true);
rotate([0, 0, -120]) translate([20, 0, 0]) rotate([0, 0, 45]) cube([20, 20, 20], center = true);
}
translate([0, 0, -1]) cylinder(r = core_d / 2, h = core_center_h, center = true);
}
//top
translate([0, 0, top_z_offset]) {
cylinder(r = core_d / 2, h = core_h + core_center_h, center = true);
}
//bottom
translate([0, 0, -(core_bottom_h / 2) - (core_center_h / 2)]) {
cylinder(r = core_bottom_d / 2, h = core_bottom_h + core_center_h, center = true);
}
}
cylinder(r = void_d / 2, h = 30, center = true);
translate([0, 0, -12]) spacer_ridges();
}
//arms
difference () {
union () {
translate([0, 0, top_z_offset]) difference() {
//adjust the shorter arm
intersection () {
cylinder(r = arms_outer_d / 2, h = core_h + core_center_h, center = true);
translate([1, 0, 0]) cylinder(r = arms_outer_d / 2, h = core_h + core_center_h, center = true);
}
intersection () {
cylinder(r = arms_inner_d / 2, h = core_h + core_center_h + 1, center = true);
translate([1, 0, 0]) cylinder(r = arms_inner_d / 2, h = core_h + core_center_h + 1, center = true);
}
translate([0, arms_outer_d / 2, 0]) cube([arms_outer_d, arms_outer_d, arms_outer_d], center = true);
}
translate([(arms_outer_d + arms_inner_d) / 4, 0, top_z_offset]) cylinder(r = 3.5 / 2, h = core_h + core_center_h, center = true, $fn = 40);
//adjusted arm
translate([-((arms_outer_d + arms_inner_d) / 4) + 1, 0, top_z_offset]) cylinder(r = 3.5 / 2, h = core_h + core_center_h, center = true, $fn = 40);
difference () {
rotate([0, 0, -120]) translate([13.75, 0, top_z_offset]) cube([16, 20, core_h + core_center_h], center = true);
//remove piece from adjusting arm
translate([-19, -14, 0]) rotate([0, 0, 10]) cube([4, 4, 30], center = true);
rotate([0, 0, -120 - 37]) translate([18, 0, top_z_offset]) {
cylinder(r = 6.8 / 2, h = 30, center = true);
translate([-4, -2, 0]) cube([4, 4, 30], center = true);
}
rotate([0, 0, -120 + 37]) translate([18, 0, top_z_offset]) {
cylinder(r = 6.8 / 2, h = 30, center = true);
translate([-4, 2, 0]) cube([4, 4, 30], center = true);
}
}
}
rotate([0, 0, -120]) translate([20, -5, 0]) rotate([0, 0, 45]) cube([20, film_void, 30], center = true);
rotate([0, 0, -120]) translate([20, 5, 0]) rotate([0, 0, -45]) cube([20, film_void, 30], center = true);
rotate([0, 0, -120]) translate([25, 0, 0]) difference () {
cylinder(r = 8 / 2, h = 30, center = true);
translate([-6.9, 0, 0]) cube([8, 8, 30], center = true);
}
cylinder(r = core_void_outer_d / 2, h = core_void_h, center = true);
rotate([0, 0, -120]) translate([20, 0, -1.5]) rotate([0, 0, 45]) cube([20, 20, 3.01], center = true);
cylinder(r = void_d / 2, h = 30, center = true);
}
}
module spiral_top (spiral_count = 40) {
outer_d = 215;
outer_d_inside = 209;
outer_h = 7.5;
spoke_len = 81;
spoke_w = 3;
spoke_h = 4.2 + 3;
spoke_2_len = 43;
spoke_2_h = 6;
translate([0, 0, -3.75]) difference () {
cylinder(r = outer_d / 2, h = outer_h, center = true, $fn = 500);
cylinder(r = outer_d_inside / 2, h = outer_h + 1, center = true, $fn = 500);
}
difference () {
spiral_top_core();
for (i = [0 : SPOKE_COUNT]) {
rotate([0, 0, (i + 0.5) * (360 / SPOKE_COUNT)]) translate([0, 26.75, 0]) cylinder(r = 2, h = 20, center = true, $fn = 40);
}
}
for (i = [0 : SPOKE_COUNT]) {
rotate([0, 0, i * (360 / SPOKE_COUNT)]) translate([(spoke_len / 2) + (48 / 2), 0, -3.6]) cube([spoke_len, spoke_w, spoke_h], center = true);
}
for (i = [0 : SPOKE_COUNT]) {
rotate([0, 0, (i + 0.5) * (360 / SPOKE_COUNT)]) translate([(outer_d / 2) - (spoke_2_len / 2) - 2, 0, -3]) cube([spoke_2_len, spoke_w, spoke_2_h], center = true);
}
for (i = [0 : SPOKE_COUNT]) {
rotate([0, 0, (i + 0.5) * (360 / SPOKE_COUNT)]) translate([63, 0, -3]) rotate([0, 0, 20]) cube([ spoke_w, 18, spoke_2_h], center = true);
}
//translate([0, 0, 1]) rotate([0, 0, 0]) spiral_2 (START_D = 46.95, SPIRALS = spiral_count);//12 //40
translate([0, 0, -.1]) spirals(spiral_count, 46.95 - 1.2, 2.075);
}
module spacer_ridges () {
ridges = 16;
for (i = [0 : ridges]) {
rotate([0, 0, i * (360 / ridges)]) translate([13.5, 0, 0]) cylinder(r = 1.25, h = 8, $fn = 60);
}
}
module spacer_ridges_loose () {
ridges = 16;
intersection () {
union () {
for (i = [0 : ridges]) {
rotate([0, 0, i * (360 / ridges)]) translate([13.7, 0, 0]) cylinder(r = 1.25, h = 8, $fn = 60);
}
}
cylinder(r = 13.7, h = 12, center = true);
}
}
module spacer_outer_ridges () {
ridges = 24;
H = 6.5;
difference () {
union () {
for (i = [0 : ridges]) {
rotate([0, 0, i * (360 / ridges)]) translate([14.6, 0, -4.75]) cylinder(r = 1.25, h = 8, $fn = 30);
}
}
translate([0, 0, -4.1]) difference () {
cylinder(r = 33 / 2, h = 4, center = true, $fn = 100);
cylinder(r2 = 33 / 2, r1 = 27.75 / 2, h = 4.1, center = true, $fn = 100);
}
}
}
module spacer () {
add = 3.25;
core_d = 29.5;
core_bottom_d = 26.2 + .2;
void_d = 22.5;
h = 8 + add;
translate([0, 0, (add / 2) - 1]) difference () {
union () {
difference () {
cylinder(r = core_d / 2, h = h, center = true, $fn = 200);
translate([0, 0, 8]) cylinder(r = core_bottom_d / 2, h = h, center = true, $fn = 200);
cylinder(r = void_d / 2, h = h + 1, center = true, $fn = 200);
}
translate([0, 0, 0]) spacer_ridges_loose();
spacer_outer_ridges();
}
//trim top
translate([0, 0, h - 0.1]) cylinder(r = (core_d + 1) / 2, h = h, center = true, $fn = 200);
//trim bottom
translate([0, 0, -h + 0.9]) cylinder(r = (core_d + 1) / 2, h = h, center = true, $fn = 200);
//finger grips
//translate([0, 24, 0]) rotate([-6, 0, 0]) cylinder(r = 10, h = 6, center = true, $fn = 100);
//translate([0, -24, 0]) rotate([6, 0, 0]) cylinder(r = 10, h = 6, center = true, $fn = 100);
}
}
module top () {
H = 5;
center_d = 53;
spoke_w = 4.5;
spokes = 12;
outer_d = 215;
inner_d = 150;
void_d = 22.5;
hole_d = 3.5;
hole_spacing = 37;
core_d = 29.5;
core_bottom_d = 26.2;
difference () {
union () {
cylinder(r = center_d / 2, h = H, center = true, $fn = 100);
for (i = [0 : spokes]) {
rotate([0, 0, i * (360 / spokes)]) translate([0, outer_d / 4, 0]) cube([spoke_w, (outer_d / 2) - 1, H], center = true);
}
}
//void
cylinder(r = void_d / 2, h = H + 1, center = true, $fn = 100);
//speed holes
for (i = [0 : 3]) {
rotate([0, 0, (i * 90) + 45]) translate([0, hole_spacing / 2, 0]) cylinder(r = hole_d / 2, h = H + 1, center = true);
}
//rounding of center cylinder
for (i = [0 : spokes]) {
rotate([0, 0, (i + 0.5) * (360 / spokes)]) translate([-2.75, 26.5, 0]) cylinder(r = 2, h = H+1, center = true, $fn = 40);
rotate([0, 0, (i + 0.5) * (360 / spokes)]) translate([2.75, 26.5, 0]) cylinder(r = 2, h = H+1, center = true, $fn = 40);
rotate([0, 0, (i + 0.5) * (360 / spokes)]) translate([0, 26.5, 0]) cube([5, 4, H + 1], center = true);
}
}
difference () {
cylinder(r = (center_d / 2) - 1.8, h = H, center = true, $fn = 200);
cylinder(r = (hole_spacing / 2) + 2, h = H + 1, center = true, $fn = 200);
}
//outer ring
difference () {
cylinder(r = outer_d / 2, h = H, center = true, $fn = 200);
cylinder(r = (outer_d / 2) - 5, h = H + 1, center = true, $fn = 200);
}
//inner ring
difference () {
cylinder(r = inner_d / 2, h = H, center = true, $fn = 200);
cylinder(r = (inner_d / 2) - 5, h = H + 1, center = true, $fn = 200);
}
//rounded cross connectors
for (i = [0 : spokes]) {
rotate([0, 0, i * (360 / spokes)]) translate([0, (inner_d / 2) - (spoke_w / 2), 0]) difference() {
cylinder(r = 6.5, h = H, center = true);
translate([6.25, 6, 0]) cylinder(r = 4, h = H + 1, center = true, $fn = 60);
translate([-6.25, 6, 0]) cylinder(r = 4, h = H + 1, center = true, $fn = 60);
translate([-6.1, -7, 0]) cylinder(r = 4, h = H + 1, center = true, $fn = 60);
translate([6.1, -7, 0]) cylinder(r = 4, h = H + 1, center = true, $fn = 60);
}
}
difference () {
union () {
translate([0, 0, 3.75 + 1]) cylinder(r = core_d / 2, h = H, center = true, $fn = 60);
translate([0, 0, 3.75 + 1 + 3.2]) cylinder(r = core_bottom_d / 2, h = H, center = true, $fn = 60);
}
cylinder(r = void_d / 2, h = H * 5 , center = true, $fn = 100);
translate([0, 0, 4 + 1 + 2.25]) spacer_ridges();
}
//rounded outer ring connectors
for (i = [0 : spokes]) {
rotate([0, 0, i * (360 / spokes)]) translate([0, 205 / 2, 0]) difference () {
cube([13, 9, H], center = true);
translate([6.2, -4.2, 0]) cylinder(r = 4, h = H + 1, center = true, $fn = 60);
translate([-6.2, -4.2, 0]) cylinder(r = 4, h = H + 1, center = true, $fn = 60);
}
}
}
module spiral_facet_2 (i, SPIRAL, START_R = 48, SPACING = 2, FACET_SIZE = 1, FN = 360) {
BOTTOM_T = 1.2;
TOP_T = .3;
H = 2.1;
STEP_SIZE = SPACING / FN;
STEP_OFFSET = (SPIRAL * SPACING) + (i * STEP_SIZE);
ROT = i* (360 / FN);
ANGLE = 0;
OFFSET = START_R + STEP_OFFSET;
rotate([0, 0, ROT]) translate ([OFFSET, 0, - H / 2]) {
rotate ([0, 0, ANGLE]) {
hull () {
translate([0, 0, H])
cube([TOP_T, FACET_SIZE, 0.1], center=true);
cube([BOTTOM_T, FACET_SIZE, 0.1], center=true);
}
}
}
}
module spiral_2 (SPIRALS = 40, START_D = 48) {
SPACING = 2.075;
FACET_SIZE = 2;
for (SPIRAL = [0 : SPIRALS - 1]) {
//C = PI * R^2
C = PI * pow(( (START_D / 2) + (SPIRAL * SPACING) ) / 2, 2);
FN = ceil( C / FACET_SIZE );
for (i = [0 : FN - 1]) {
spiral_facet_2(i, SPIRAL, START_D / 2, SPACING, FACET_SIZE, FN);
}
}
}
module spirals (count = 40, start_d = 48, spacing = 2) {
facet_size = 30;
bottom = 1.2;
top = .3;
top_offset = (bottom - top);
h = 2.2;
od = start_d + (spacing * 2 * count);
echo("SPIRAL LENGTH", PI * count * (od + start_d + 1) / 2);
echo("OUTER D", od);
facetProfile = [[0, 0], [top_offset, -h], [bottom, -h], [bottom, 0]];
union () {
for (s = [0 : count - 1]) {
d = start_d + (s * spacing * 2);
c = PI * pow(d / 2, 2);
$fn = ceil( c / facet_size );
angle_i = 360 / $fn;
increment = spacing / $fn;
spiralPath = [ for(t = [0 : $fn + 1]) [((d / 2) + (t * increment)) * cos(t * angle_i), ((d / 2) + (t * increment)) * sin(t * angle_i), 0] ];
path_extrude(exShape=facetProfile, exPath=spiralPath);
}
}
}
module spirals_compressed (count = 40, start_d = 48, spacing = 2 ) {
facet_size = 30;
bottom = 1.2;
top = .3;
top_offset = (bottom - top);
h = 2.2;
facetProfile = [[0, 0], [top_offset, -h], [bottom, -h], [bottom, 0]];
spiralPath = [ for (s = [0 : count - 1]) for(t = [0 : ceil( (PI * pow((start_d + (s * spacing * 2)) / 2, 2)) / facet_size ) - 1]) [(((start_d + (s * spacing * 2)) / 2) + (t * (spacing / ceil( (PI * pow((start_d + (s * spacing * 2)) / 2, 2)) / facet_size )))) * cos(t * (360 / ceil( (PI * pow((start_d + (s * spacing * 2)) / 2, 2)) / facet_size ))), (((start_d + (s * spacing * 2)) / 2) + (t * (spacing / ceil( (PI * pow((start_d + (s * spacing * 2)) / 2, 2)) / facet_size )))) * sin(t * (360 / ceil( (PI * pow((start_d + (s * spacing * 2)) / 2, 2)) / facet_size ))), 0] ];
path_extrude(exShape=facetProfile, exPath=spiralPath);
}

@ -0,0 +1,195 @@
// path_extrude.scad -- Extrude a path in 3D space
// usage: add "use <path_extrude.scad>;" to the top of your OpenSCAD source code
// Copyright (C) 2014-2019 David Eccles (gringer) <bioinformatics@gringene.org>
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
// You should have received a copy of the GNU General Public License
// along with this program. If not, see <https://www.gnu.org/licenses/>.
// Determine the projection of a point on a plane centered at c1 with normal n1
function project(p, c, n) =
p - (n * (p - c)) * n / (n * n);
// determine angle between two points with a given normal orientation
// see https://stackoverflow.com/questions/14066933/
// direct-way-of-computing-clockwise-angle-between-2-vectors
// dot = p1 * p2;
// det = (p1[0]*p2[1]*n1[2] + p2[0]*n1[1]*p1[2] + n1[0]*p1[1]*p2[2]) -
// (n1[0]*p2[1]*p1[2] + p1[0]*n1[1]*p2[2] + p2[0]*p1[1]*n1[2]);
// atan2(det, dot);
// determine angle between two planar points and a centre
// with a given normal orientation
function getPlanarAngle(p1, p2, c1, n1) =
let(p1 = p1-c1, n1=n1 / norm(n1), p2=p2-c1)
atan2((p1[0]*p2[1]*n1[2] + p2[0]*n1[1]*p1[2] + n1[0]*p1[1]*p2[2]) -
(n1[0]*p2[1]*p1[2] + p1[0]*n1[1]*p2[2] + p2[0]*p1[1]*n1[2]), p1 * p2);
function c3D(tPoints) =
(len(tPoints[0]) == undef) ? // single point
c3D([tPoints])[0] :
(len(tPoints[0]) < 3) ? // collection of 2D points
tPoints * [[1,0,0],[0,1,0]] :
tPoints; // 3D points
// translate a point (or points)
function myTranslate(ofs, points, acc = []) =
(len(points[0]) == undef) ?
myTranslate(ofs, [points])[0] :
[ for(i = [0:(len(points) - 1)])
[ for(d = [0:(len(points[0])-1)]) (ofs[d] + points[i][d])]];
// rotate a point (or points)
function myRotate(rotVec, points) =
let(rotX = [[1, 0, 0],
[0, cos(rotVec[0]), -sin(rotVec[0])],
[0, sin(rotVec[0]), cos(rotVec[0])]],
rotY = [[ cos(rotVec[1]), 0,-sin(rotVec[1])],
[ 0, 1, 0],
[ sin(rotVec[1]), 0, cos(rotVec[1])]],
rotZ = [[ cos(rotVec[2]), sin(rotVec[2]), 0],
[ sin(rotVec[2]), -cos(rotVec[2]), 0],
[0, 0, 1]])
(len(points[0]) == undef) ?
myRotate(rotVec, [points])[0] :
c3D(points) * rotX * rotY * rotZ;
// Determine spherical rotation for cartesian coordinates
function rToS(pt) =
[-acos((pt[2]) / norm(pt)),
0,
-atan2(pt[0],pt[1])];
function calcPreRot(p1, p2, p3) =
let(n1=p2-p1, // normal between the two points (i.e. the plane that the polygon sits on)
n2=p3-p2,
rt1=rToS(n1),
rt2=rToS(n2),
pj1=(p2 + myRotate(rt2, [[1e42,0,0]])[0]),
pj2=project(p=(p1 + myRotate(rt1, [[1e42,0,0]])[0]), c=p2, n=n2))
getPlanarAngle(p1=pj1, p2=pj2, c1=p2, n1=n2);
function cumSum(x, res=[]) =
(len(x) == len(res)) ? concat([0], res) :
(len(res) == 0) ? cumSum(x=x, res=[x[0]]) :
cumSum(x=x, res=concat(res, [x[len(res)] + res[len(res)-1]]));
// Create extrusion side panels for one polygon segment as triangles.
// Note: panels are not necessarily be planar due to path twists
function makeSides(shs, pts, ofs=0) =
concat(
[for(i=[0:(shs-1)]) [i+ofs, ((i+1) % shs + ofs + shs) % (shs * pts),
(i+1) % shs + ofs]],
[for(i=[0:(shs-1)]) [((i+1) % shs + ofs + shs) % (shs * pts),
i+ofs, (i + ofs + shs) % (shs * pts)]]);
// Concatenate the contents of the outermost list
function flatten(A, acc = [], aDone = 0) =
(aDone >= len(A)) ? acc :
flatten(A, acc=concat(acc, A[aDone]), aDone = aDone + 1);
// Linearly interpolate between two shapes
function makeTween(shape1, shape2, t) =
(t == 0) ? shape1 :
(t == 1) ? shape2 :
[for (i=[0:(len(shape1)-1)])
(shape1[i]*(1-t) + shape2[i % len(shape2)]*(t))];
// Extrude a 2D shape through a 3D path
// Note: merge has two effects:
// 1) Removes end caps
// 2) Adjusts the rotation of each path point
// so that the end and start match up
module path_extrude(exPath, exShape, exShape2=[],
exRots = [0], exScale = [1], merge=false, preRotate=true){
exShapeTween = (len(exShape2) == 0) ?
exShape : exShape2;
shs = len(exShape); // shs: shape size
pts = len(exPath); // pts: path size
exPathX = (merge) ? concat(exPath, [exPath[0], exPath[1]]) :
concat(exPath,
[exPath[pts-1] + (exPath[pts-1] - exPath[pts-2]),
exPath[pts-1] + 2*(exPath[pts-1] - exPath[pts-2])]);
exScaleX = (len(exScale) == len(exPath)) ? exScale :
[for (i = [0:(pts-1)]) exScale[i % len(exScale)]];
preRots = [for(i = [0:(pts-1)])
preRotate ?
calcPreRot(p1=exPathX[i], // "current" point on the path
p2=exPathX[(i+1)], // "next" point on the path
p3=exPathX[(i+2)]) :
0 ];
cumPreRots = cumSum(preRots);
seDiff = cumPreRots[len(cumPreRots)-1]; // rotation difference (start - end)
// rotation adjustment to get start to look like end
seAdj = -seDiff / (len(cumPreRots));
adjPreRots = (!merge) ? cumPreRots :
[for(i = [0:(pts-1)]) (cumPreRots[i] + seAdj * i)];
adjExRots = (len(exRots) == 1) ?
[for(i = [0:(len(adjPreRots)-1)]) (adjPreRots[i] + exRots[0])] :
[for(i = [0:(len(adjPreRots)-1)]) (adjPreRots[i] + exRots[i % len(exRots)])];
phPoints = flatten([
for(i = [0:(pts-1)])
let(p1=exPathX[i],
p2=exPathX[(i+1)],
n1=p2-p1, // normal between the two points
rt1=rToS(n1))
myTranslate(p1, myRotate(rt1, myRotate([0,0,-adjExRots[i]],
c3D(makeTween(exShape, exShapeTween, i / (pts-1)) *
exScaleX[i]))))
]);
if(merge){ // just the surface, no end caps
polyhedron(points=phPoints,
faces=flatten([
for(i = [0:(pts-1)])
makeSides(shs, pts, ofs=shs*i)
])
);
} else {
polyhedron(points=phPoints,
faces=concat(
flatten([
for(i = [0:(pts-2)])
makeSides(shs, pts, ofs=shs*i)
]),
concat( // add in start / end covers
[[for(i= [0:(shs-1)]) i]],
[[for(i= [(len(phPoints)-1):-1:(len(phPoints)-shs)]) i]]
)
));
}
}
myPathTrefoil = [ for(t = [0:(360 / 101):359]) [ // trefoil knot
5*(.41*cos(t) - .18*sin(t) - .83*cos(2*t) - .83*sin(2*t) -
.11*cos(3*t) + .27*sin(3*t)),
5*(.36*cos(t) + .27*sin(t) - 1.13*cos(2*t) + .30*sin(2*t) +
.11*cos(3*t) - .27*sin(3*t)),
5*(.45*sin(t) - .30*cos(2*t) +1.13*sin(2*t) -
.11*cos(3*t) + .27*sin(3*t))] ];
myPointsOctagon =
let(ofs1=15)
[ for(t = [0:(360/8):359])
((t==90)?1:2) * [cos(t+ofs1),sin(t+ofs1)]];
myPointsChunkOctagon =
let(ofs1=15)
[ for(t = [0:(360/8):359])
((t==90)?0.4:1.9) *
[cos((t * 135/360 + 45)+ofs1+45)+0.5,sin((t * 135/360 + 45)+ofs1+45)]];
//myPoints = [ for(t = [0:(360/8):359]) 2 * [cos(t+45),sin(t+45)]];
pts=[2,0,0.5];
/*translate([0,0,0]) {
path_extrude(exRots = [$t*360], exShape=myPointsOctagon,
exPath=myPathTrefoil, merge=true);
}*/

@ -0,0 +1,3 @@
include <./gnal_50ft.scad>;
spacer();

@ -0,0 +1,3 @@
include <./gnal_50ft.scad>;
spiral_bottom();

@ -0,0 +1,3 @@
include <./gnal_50ft.scad>;
spiral_top();

@ -0,0 +1,372 @@
/*
* ISO-standard metric threads, following this specification:
* http://en.wikipedia.org/wiki/ISO_metric_screw_thread
*
* Copyright 2017 Dan Kirshner - dan_kirshner@yahoo.com
* This program is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* See <http://www.gnu.org/licenses/>.
*
* Version 2.3. 2017-08-31 Default for leadin: 0 (best for internal threads).
* Version 2.2. 2017-01-01 Correction for angle; leadfac option. (Thanks to
* Andrew Allen <a2intl@gmail.com>.)
* Version 2.1. 2016-12-04 Chamfer bottom end (low-z); leadin option.
* Version 2.0. 2016-11-05 Backwards compatibility (earlier OpenSCAD) fixes.
* Version 1.9. 2016-07-03 Option: tapered.
* Version 1.8. 2016-01-08 Option: (non-standard) angle.
* Version 1.7. 2015-11-28 Larger x-increment - for small-diameters.
* Version 1.6. 2015-09-01 Options: square threads, rectangular threads.
* Version 1.5. 2015-06-12 Options: thread_size, groove.
* Version 1.4. 2014-10-17 Use "faces" instead of "triangles" for polyhedron
* Version 1.3. 2013-12-01 Correct loop over turns -- don't have early cut-off
* Version 1.2. 2012-09-09 Use discrete polyhedra rather than linear_extrude ()
* Version 1.1. 2012-09-07 Corrected to right-hand threads!
*/
// Examples.
//
// Standard M8 x 1.
// metric_thread (diameter=8, pitch=1, length=4);
// Square thread.
// metric_thread (diameter=8, pitch=1, length=4, square=true);
// Non-standard: long pitch, same thread size.
//metric_thread (diameter=8, pitch=4, length=4, thread_size=1, groove=true);
// Non-standard: 20 mm diameter, long pitch, square "trough" width 3 mm,
// depth 1 mm.
//metric_thread (diameter=20, pitch=8, length=16, square=true, thread_size=6,
// groove=true, rectangle=0.333);
// English: 1/4 x 20.
//english_thread (diameter=1/4, threads_per_inch=20, length=1);
// Tapered. Example -- pipe size 3/4" -- per:
// http://www.engineeringtoolbox.com/npt-national-pipe-taper-threads-d_750.html
// english_thread (diameter=1.05, threads_per_inch=14, length=3/4, taper=1/16);
// Thread for mounting on Rohloff hub.
//difference () {
// cylinder (r=20, h=10, $fn=100);
//
// metric_thread (diameter=34, pitch=1, length=10, internal=true, n_starts=6);
//}
// ----------------------------------------------------------------------------
function segments (diameter) = min (50, ceil (diameter*6));
// ----------------------------------------------------------------------------
// diameter - outside diameter of threads in mm. Default: 8.
// pitch - thread axial "travel" per turn in mm. Default: 1.
// length - overall axial length of thread in mm. Default: 1.
// internal - true = clearances for internal thread (e.g., a nut).
// false = clearances for external thread (e.g., a bolt).
// (Internal threads should be "cut out" from a solid using
// difference ()).
// n_starts - Number of thread starts (e.g., DNA, a "double helix," has
// n_starts=2). See wikipedia Screw_thread.
// thread_size - (non-standard) axial width of a single thread "V" - independent
// of pitch. Default: same as pitch.
// groove - (non-standard) subtract inverted "V" from cylinder (rather than
// add protruding "V" to cylinder).
// square - Square threads (per
// https://en.wikipedia.org/wiki/Square_thread_form).
// rectangle - (non-standard) "Rectangular" thread - ratio depth/(axial) width
// Default: 1 (square).
// angle - (non-standard) angle (deg) of thread side from perpendicular to
// axis (default = standard = 30 degrees).
// taper - diameter change per length (National Pipe Thread/ANSI B1.20.1
// is 1" diameter per 16" length). Taper decreases from 'diameter'
// as z increases.
// leadin - 0 (default): no chamfer; 1: chamfer (45 degree) at max-z end;
// 2: chamfer at both ends, 3: chamfer at z=0 end.
// leadfac - scale of leadin chamfer (default: 1.0 = 1/2 thread).
module metric_thread (diameter=8, pitch=1, length=1, internal=false, n_starts=1,
thread_size=-1, groove=false, square=false, rectangle=0,
angle=30, taper=0, leadin=0, leadfac=1.0)
{
// thread_size: size of thread "V" different than travel per turn (pitch).
// Default: same as pitch.
local_thread_size = thread_size == -1 ? pitch : thread_size;
local_rectangle = rectangle ? rectangle : 1;
n_segments = segments (diameter);
h = (square || rectangle) ? local_thread_size*local_rectangle/2 : local_thread_size / (2 * tan(angle));
h_fac1 = (square || rectangle) ? 0.90 : 0.625;
// External thread includes additional relief.
h_fac2 = (square || rectangle) ? 0.95 : 5.3/8;
tapered_diameter = diameter - length*taper;
difference () {
union () {
if (! groove) {
metric_thread_turns (diameter, pitch, length, internal, n_starts,
local_thread_size, groove, square, rectangle, angle,
taper);
}
difference () {
// Solid center, including Dmin truncation.
if (groove) {
cylinder (r1=diameter/2, r2=tapered_diameter/2,
h=length, $fn=n_segments);
} else if (internal) {
cylinder (r1=diameter/2 - h*h_fac1, r2=tapered_diameter/2 - h*h_fac1,
h=length, $fn=n_segments);
} else {
// External thread.
cylinder (r1=diameter/2 - h*h_fac2, r2=tapered_diameter/2 - h*h_fac2,
h=length, $fn=n_segments);
}
if (groove) {
metric_thread_turns (diameter, pitch, length, internal, n_starts,
local_thread_size, groove, square, rectangle,
angle, taper);
}
}
}
// chamfer z=0 end if leadin is 2 or 3
if (leadin == 2 || leadin == 3) {
difference () {
cylinder (r=diameter/2 + 1, h=h*h_fac1*leadfac, $fn=n_segments);
cylinder (r2=diameter/2, r1=diameter/2 - h*h_fac1*leadfac, h=h*h_fac1*leadfac,
$fn=n_segments);
}
}
// chamfer z-max end if leadin is 1 or 2.
if (leadin == 1 || leadin == 2) {
translate ([0, 0, length + 0.05 - h*h_fac1*leadfac]) {
difference () {
cylinder (r=diameter/2 + 1, h=h*h_fac1*leadfac, $fn=n_segments);
cylinder (r1=tapered_diameter/2, r2=tapered_diameter/2 - h*h_fac1*leadfac, h=h*h_fac1*leadfac,
$fn=n_segments);
}
}
}
}
}
// ----------------------------------------------------------------------------
// Input units in inches.
// Note: units of measure in drawing are mm!
module english_thread (diameter=0.25, threads_per_inch=20, length=1,
internal=false, n_starts=1, thread_size=-1, groove=false,
square=false, rectangle=0, angle=30, taper=0, leadin=0,
leadfac=1.0)
{
// Convert to mm.
mm_diameter = diameter*25.4;
mm_pitch = (1.0/threads_per_inch)*25.4;
mm_length = length*25.4;
echo (str ("mm_diameter: ", mm_diameter));
echo (str ("mm_pitch: ", mm_pitch));
echo (str ("mm_length: ", mm_length));
metric_thread (mm_diameter, mm_pitch, mm_length, internal, n_starts,
thread_size, groove, square, rectangle, angle, taper, leadin,
leadfac);
}
// ----------------------------------------------------------------------------
module metric_thread_turns (diameter, pitch, length, internal, n_starts,
thread_size, groove, square, rectangle, angle,
taper)
{
// Number of turns needed.
n_turns = floor (length/pitch);
intersection () {
// Start one below z = 0. Gives an extra turn at each end.
for (i=[-1*n_starts : n_turns+1]) {
translate ([0, 0, i*pitch]) {
metric_thread_turn (diameter, pitch, internal, n_starts,
thread_size, groove, square, rectangle, angle,
taper, i*pitch);
}
}
// Cut to length.
translate ([0, 0, length/2]) {
cube ([diameter*3, diameter*3, length], center=true);
}
}
}