takeup/examples/JK_projector_takeup.scad

include <../takeup.scad>;

PART="none";

ARM_LENGTH = 130;
ARM_WIDTH = 15;
ARM_HEIGHT = 7;
ARM_CUTOFF = 101.25;

ARM_REINFORCEMENT_OFFSET_X = 20;
ARM_REINFORCEMENT_Y = 5;
ARM_REINFORCEMENT_Z = 4.1;

ARMS_ANGLE = 40;

AX = 105;
AY = 26.85;
AZ = 6.1;
    
BX = 105;
BY = 34.4;
BZ = 5;

BOLTSX = 77;

M5 = 5;

FILTER_X = 55.4;
FILTER_Y = 6.5;
FILTER_VOID_X = FILTER_X - 9 + ((4.5 - 2.34) * 2);

ROLLER_SPACING = 95;

module m5_nut () {
    cylinder(r = R(9.4), h = 4, center = true, $fn = 6);
}

module block () {
    cube([AX, AY, AZ], center = true);
    translate([0, -(AY - BY) / 2, (AZ / 2) + (BZ / 2)]) {
        difference () {
            union () {
                cube([BX, BY, BZ], center = true);
                translate([BOLTSX / 2, (BY / 2) - 3.5, 0]) {
                    cylinder(r= R(13), h = BZ, center = true, $fn = 60);
                }
                translate([-BOLTSX / 2, (BY / 2) - 3.5, 0]) {
                    cylinder(r= R(13), h = BZ, center = true, $fn = 60);
                }
            }
            translate([0, BY - 5.44, 0]) cube([53.2, BY, BZ + 1], center = true);
            //bolts
            translate([0, (BY / 2) - 3.5, 0]) {
                translate([BOLTSX / 2, 0, 0]) {
                    cylinder(r = 4.95 / 2, h = BZ + 1, center = true, $fn = 50);
                    translate([0, 0, 3]) m5_nut();
                }
                translate([-BOLTSX / 2, 0, 0]) {
                    cylinder(r = 4.95 / 2, h = BZ + 1, center = true, $fn = 50);
                    translate([0, 0, 3]) m5_nut();
                }
            }   
        }
    }
}

module original_takeup () {
    block();
}

module projector_mount () {
	//intersection () {}
	$fn = 60;
	intersection () {
		rotate([0, 180, 0]) minimal_mount();
		translate([-10, 0, 0]) rounded_cube([50, 30, 20], d = 12, center = true);
	}
	//translate([-8.5, 0, 12])  rotate([0, 0, 180]) geared_motor();
    //translate([0, 0, -34]) rotate([180, 0, 0]) daylight_spool_insert();
}

module projector_arm () {
	difference () {
		union () {
			cube([ARM_LENGTH, ARM_WIDTH, ARM_HEIGHT], center = true);
			translate([(ARM_CUTOFF/2) - 2.1, 0, 0]) scale([2, 1, 1]) rotate([0, 0, 45]) cube([30, 30, ARM_HEIGHT], center = true);
		}
		translate([ARM_CUTOFF, 0, 0]) cube([ARM_LENGTH, 52, ARM_HEIGHT + 1], center = true);
	}
    translate([-ARM_REINFORCEMENT_OFFSET_X / 2, 0, -ARM_REINFORCEMENT_Z / 2]) difference() {
        cube([ARM_LENGTH - ARM_REINFORCEMENT_OFFSET_X, ARM_REINFORCEMENT_Y, ARM_HEIGHT + ARM_REINFORCEMENT_Z], center = true);
        translate([0, 0, -ARM_HEIGHT - ARM_REINFORCEMENT_Z + 2]) rotate([0, -5, 0]) cube([ARM_LENGTH - ARM_REINFORCEMENT_OFFSET_X + 20, ARM_REINFORCEMENT_Y + 1, ARM_HEIGHT + ARM_REINFORCEMENT_Z], center = true);
    }
}

module filter_holder () {
    difference () {
        cube([FILTER_X, 13.25, 50.5], center = true);
        //center void
        cube([42.4, 13.25 + 1, 50.5 + 1], center = true);
        translate([0, (13.25/2) - (3.25/2) - 1, 0]) cube([FILTER_VOID_X, 3.25, 50.5 + 1], center = true);
        translate([0, (13.25/2) - (3.25/2) - 1 - 3.25 - 1, 0]) cube([FILTER_VOID_X, 3.25, 50.5 + 1], center = true);
    }
}

module filter_reinforcement () {
    Z = 19.5 + 7.83-5.75;
    X = AX;
    difference () {
        cube([X, 15.5, Z], center = true);
        cube([FILTER_X - 0.1, 15.5 + 1, Z + 1], center = true);
        translate([X - 19.5, -9, 0]) cube([X, 15.5, Z + 1], center = true);
        translate([-X + 19.5, -9, 0]) cube([X, 15.5, Z + 1], center = true);
    }
}

module roller_bolts () {
    translate([ROLLER_SPACING/2, 2, 0]) {
        cylinder(r = R(4.25), h = 80, center = true, $fn = 40);
        translate([0, 0, 7]) rotate([0, 0, 30]) m4_nut();
    }
    translate([-ROLLER_SPACING/2, 2, 0]) {
        cylinder(r = R(4.25), h = 80, center = true, $fn = 40);
        translate([0, 0, 7]) rotate([0, 0, 30]) m4_nut();
    }
}

module jk_takeup () {
    difference () {
        union () {
            block();
            translate([0, 0, -27.5]) filter_holder();
            translate([0, -1.1, -16+(5.75/2)]) filter_reinforcement();
        }
        roller_bolts();
    }
    translate([0, 0, 1.8]) {
        translate([-30, 0, 0]) rotate([0, 0, ARMS_ANGLE]) {
            translate([-ARM_LENGTH/2, 0, 2.75]) rotate([0, 0, 180]) projector_arm();
            translate([-ARM_LENGTH, 0, 5.5]) rotate([0, 0, 180]) projector_mount();
        }
        translate([30, 0, 0]) rotate([0, 0, -ARMS_ANGLE]) {
            translate([ARM_LENGTH/2, 0, 2.75]) projector_arm();
            translate([ARM_LENGTH, 0, 5.5]) projector_mount();
        }
    }
}

module jk_takeup_halves (HALF = "A") {
    difference () {
        jk_takeup();
        translate([0, 7, 0]) cylinder(r = R(M5), h = 40, center = true, $fn = 60);
        translate([0, -7, 0]) cylinder(r = R(M5), h = 40, center = true, $fn = 60);
        if (HALF == "A") {
            translate([(ARM_LENGTH) + 10, 0, 0]) cube([ARM_LENGTH * 2, ARM_LENGTH * 2, ARM_LENGTH], center = true);
            translate([0, 0, 10 + 2]) cube([20, BY + 1, 20], center = true);
        } else if (HALF == "B") {
            translate([-(ARM_LENGTH) - 10, 0, 0]) cube([ARM_LENGTH * 2, ARM_LENGTH * 2, ARM_LENGTH], center = true);
            translate([0, 0, -10 + 2]) cube([20, BY + 1, 20], center = true);
        }
    }

}

//translate([0, 0, 40]) color("red") original_takeup();
//jk_takeup();
jk_takeup_halves();
//color("blue") jk_takeup_halves("B");
//m5_nut();