#include "finish.inc"
#include "transforms.inc"
#include "colors.inc"
#include "textures.inc"
#include "metals.inc"

// ********************
// *** CIE+lightsys ***
// ********************
#include "CIE.inc"
#declare ColSys=sRGB_ColSys;
CIE_ColorSystemWhitepoint(ColSys,Blackbody2Whitepoint(4000))
#include "rspd_jvp.inc" // material samples

#include "lightsys.inc"
#include "lightsys_constants.inc"
#include "lightsys_colors.inc"
#declare Lightsys_Brightness=6; 

#declare p_micro2=
pigment{
  crackle turbulence 1
  color_map{
    [0.00 White*.7]
    [0.01 White*.7]
    [0.02 White]
    [1.00 White]
  }
  scale 5
}
#declare p_micro1=
pigment{
 cells 
 turbulence .5
 color_map{
  [0.0 White*.9]
  [1.0 White]
 }
 scale .01
}
// + average all the normals
#declare p_brushed_new=
pigment{
 average turbulence 0
 pigment_map{
  [0.0 p_micro1]
  [0.1 p_micro1 rotate 45*x]
  [0.2 p_micro1 rotate -45*x]
  [0.3 p_micro2]
  [0.4 p_micro1 rotate 45*y]
  [0.5 p_micro1 rotate -45*y]
  [0.6 p_micro1 rotate 90*z]
  [0.7 p_micro2 rotate 45]
  [0.8 p_micro1 rotate 45*z]
  [0.9 p_micro1 rotate 90*y]
  [1.0 p_micro1 rotate -45*z]
 }
 scale .1
}


#declare n_brushed_new = normal{
  pigment_pattern{
    p_brushed_new
  } 
  .4
}

#declare iron_metal = texture{
  pigment{
    //  rgb ReflectiveSpectrum(RS_BoltMetal2)
    //  rgb ReflectiveSpectrum(RS_Nickel1)
    //  rgb ReflectiveSpectrum(RS_NickelBrass1)
    rgb ReflectiveSpectrum(RS_NordicGold1)
    //  rgb ReflectiveSpectrum(RS_Iron)
    //  rgb ReflectiveSpectrum(RS_StainlessSteel1)
  }
  finish{
    Metal
  }
  normal{
    n_brushed_new .5
  }
}

#declare gray_plastic = texture{
  pigment { Gray35 }
  finish {
    ambient .1
    diffuse .6
    phong .75
    phong_size 25
  }
}

#declare white_plastic = texture{
  pigment { Gray95 }
  finish {
    ambient .1
    diffuse .6
    phong .75
    phong_size 25
  }
}

#declare yellow_plastic = texture{
  pigment { BrightGold }
  finish {
    ambient .1
    diffuse .6
    phong .75
    phong_size 25
  }
}